You are looking at historical revision 29526 of this page. It may differ significantly from its current revision.
Mini-tutorial on explicit (and implicit) renaming macros in Chicken
The following is an attempt to explain, how to write hygienic macros in Chicken with explicit renaming. It supposes, that the reader knows, how to write other low-level-macros like define-macro in Chicken-3 and other Schemes or defmacro in Lisp. As you will see, explicit renaming macros are even easier to write than those with define-macro. This is because there is a brute force method to avoid variable capture.
Let's consider a trivial macro a la Chicken-3 without any considerations on hygiene and variable capture:
(define-macro (swap! x y) ; wrong `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp)))
You might be surprised, but the replacement text, that within the backquotes, need not be changed in an explicit renaming macro, at least in a first step. What has to be changed, is the signature: explicit renaming transformers are always procedures of three variables, usually called form, rename, compare?, which has to be wrapped into an er-macro-transformer call:
(define-syntax swap! (er-macro-transformer (lambda (form rename compare?) ... `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp)))))
and you have to destructure the form argument, which is the whole macro-from, (swap! x y) in the example, to fill in the ellipsis above. That is
(define-syntax swap! ; wrong (er-macro-transformer (lambda (form rename compare?) (let ((x (cadr form)) (y (caddr form))) `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp))))))
In this form, the new macro is the same as our first attempt with define-macro. We haven't bothered about variable capture or hygiene at all. But this macro already works. You can test it, say with
(let ((x 'x) (y 'y)) (swap! x y) (list x y))
and see if it does what it is supposed to do. Of course, it is not correct, since if a client uses tmp as one of his or her arguments, the macro will crash.
In the classical macro systems, defmacro in Common Lisp or define-macro in some Schemes, you now have to think carefully, which macro variables are in danger of variable capture and use an uninterned symbol for them, tmp in the current example. Worse than that, contrary to Common Lisp, Scheme allows to use any name for variables, even keyword names as let, set!, ... so that define-macro can never create a hygienic swap! macro. Here is, where renaming comes into the play. You don't need gensym, use rename instead. And you needn't bother, which symbol to rename, rename all.
What does that mean, "all"? It's easy in the present example, everything within the backquote, except those symbols, which are already unquoted. But in more complicated examples, you should use expand, to see the replacement text of your macro calls.
(pp (expand '(swap! x y)))
will result in the replacement text
(let ((tmp x)) (set! x y) (set! y tmp))
Only x and y are arguments of your swap! call, hence everything else in the replacement text should be renamed: namely let, tmp and set!. So a hygienic version of swap! would be
(define-syntax swap! (er-macro-transformer (lambda (form rename compare?) (let ((x (cadr form)) (y (caddr form))) `(,(rename 'let) ((,(rename 'tmp) ,x)) (,(rename 'set!) ,x ,y) (,(rename 'set!) ,y ,(rename 'tmp)))))))
If you repeat the expand call above, you will get the same replacement text, but with numbers suffixed to the renamed symbols, something like
(let11 ((tmp12 x)) (set!13 x y) (set!13 y tmp12))
These renamed symbols have the same meaning as the original names without suffixes, but serve as aliases which the client cannot use under any circumstances.
Note, that the two appearances of tmp and set! are renamed to the same alias, the rename operator is referentially transparent. Note also, that these renamed symbols are much easier to interpret than gensym'ed ones!
I personally do not like these rename calls within the backquoted expression, because you loose the visual similarity between the backquoted expression and the resulting replacement text. Therefore I prefer this version, which is equivalent
(define-syntax swap! (er-macro-transformer (lambda (form rename compare?) (let ( (x (cadr form)) (y (caddr form)) (%tmp (rename 'tmp)) (%let (rename 'let)) (%set! (rename 'set!)) ) `(,%let ((,%tmp ,x)) (,%set! ,x ,y) (,%set! ,y ,%tmp))))))
You can think of the two characters ,% in the template as an identity operator.
We havn't used the compare? argument in the transformer in this example. What's its role?
Well, some macros use special symbols verbatim, else and => in cond for example. With compare? it's possible to check, if these symbols, which might appear verbatim in a list, have the same meaning as their renamed variants (rename 'else), (rename '=>). For example, if else appears as the car of a list, lst say, you can code something like
(if (compare? (car lst) (rename 'else)) ...)
You see, explicit renaming macros are a bit more verbose than classical ones with define-macro. But everybody who is able to write the latter, is able to write the former as well. It's even easier!
Implicit renaming macros
But it can still be improved. Above, I said "You need'nt bother which symbol to rename, rename all". Well, "all" is something which can perfectly be done by a machine. Consequently, since the advent of Chicken version 4.7, there is another low level macro system, based on ir-macro-transformer, which does this "rename all" in the background.
In explicit renaming macros, I had to tell the compiler explicitly, what to rename. Every symbol not renamed would break hygiene. In implicit renaming macros, the roles are reversed: I have to tell the compiler explicitly, which symbol should break hygiene, everything else is renamed, whence hygienic. A hygienic swap! macro now looks like this
(define-syntax swap! (ir-macro-transformer (lambda (form inject compare?) (let ((x (cadr form)) (y (caddr form))) `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp))))))
Note, that the second argument to the transformer is now called inject. It's used to "inject" a symbol unrenamed into the replacement text. Note further, that there is no need to gensym tmp as in define-macro. And last but not least, it's obligatory to wrap the transformer into an ir-macro-transformer call: the compiler must know, which low-level system to compile, after all.
For implicit renaming macros, the third argument to the transformer is now used a bit differently, for example
(if (compare? 'else (car lst)) ...)
Destructuring the macro-code
Up to now, we have always destructured the macro-code, (swap! x y), by hand. define-macro did it automatically. Is there a way to do it automatically with explicit- and implicit-renaming-macros as well?
Yes, there is. I've written a module, list-bindings, which exports two macros to make the definition of low-level-macros easy, define-ir-macro and define-er-macro. Both destructure the macro-code automatically using a bind macro, exported by that module as well. And both simplify injecting and renaming as well as comparing by simply providing lists of symbols. In the injecting case it is the list of identifiers to be injected, whereas in the renaming case it is a list of the form (prefix . prefixed-identifiers). All prefixed-identifiers are bound to the renamed version of itself with the common prefix stripped. Usually it's a rather long list, which is updated in the process of macro-writing. Similarly, in the comparing case, the list is either empty or of the form (suffix . suffixed-keywords). The suffix is ? in most cases, since the suffixed-keywords are predicates which check, if their only argument compares to its own name with the suffix stripped.
For details see
Here is our running example
(define-ir-macro (swap! x y) (injecting () (comparing () `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp)))))
Note, that the header of this macro shows nicely, that it is hygienic (no symbols injected) and that no additional keywords are used. If there were keywords, else and => say, the comparing clause would look like
(comparing (? else? =>?) ...
and if we had written our macro with explicit renaming, it looked like
(define-er-macro (swap! x y) (renaming (% %let %tmp %set!) (comparing () `(,%let ((,%tmp ,x)) (,%set! ,x ,y) (,%set! ,y tmp)))))
which is not as elegant as the implicit-renaming version, since it exposes in the renaming clause some details of the implementation without exposing the hygiene status.
In case there are neither injections nor comparisons, you can also redefine your old friend define-macro, now hygienic:
(define-syntax define-macro (syntax-rules () ((_ form . body) (define-ir-macro form (injecting () (comparing () . body))))))
and come back where we started
(define-macro (swap! x y) `(let ((tmp ,x)) (set! ,x ,y) (set! ,y tmp)))
Low level macros are really great ...
Jun 09, 2009
Aug 05, 2013